获取远程网页内容实例代码

 Function getHTTPPage(url) 'Asp 获取远程网页内容实例代码
  dim http
  set http=Server.createobject("Microsoft.XMLHTTP")'建立XMLHTTP对象
  Http.open "GET",url,false '设置http对象打开方式 GET方式，URL[连接页面地址]，同步处理
  Http.send() '发送请求
  if Http.readystate<>4 then'对象处理状态为 非结束
     exit function '退出函数
  end if
  getHTTPPage=bytesToBSTR(Http.responseBody,"gb2312")'BytesToBstr获取的源码转换为中文的代码
  set http=nothing '清除对象
  if err.number<>0 then err.Clear  '清除错误
 End function

'==================================================
'函数名：BytesToBstr
'作 用：将获取的源码转换为中文
'参 数：Body ------要转换的变量
'参 数：Cset ------要转换的类型
'==================================================   
 Function BytesToBstr(body,Cset)'BytesToBstr获取的源码转换为相应的代码
  dim objstream
  set objstream = Server.CreateObject("adodb.stream")
  objstream.Type = 1
  objstream.Mode =3
  objstream.Open
  objstream.Write body
  objstream.Position = 0
  objstream.Type = 2
  objstream.Charset = Cset
  BytesToBstr = objstream.ReadText
  objstream.Close
  set objstream = nothing
 End Function